***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 20, 2023                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4463AP-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    505u TC=3m
Rg     g1    g2    11.5
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=19.5  VTO=-1.96  THETA=0  VMAX=1.5e5  ETA=0  LEVEL=3  GAMMA=1.5)
Rd     d1    d2    50.82m  TC=6m
Dbd    d2    s2    Dbt
.MODEL     Dbt    D(BV=66  TBV1=4.6e-4  M=0.486  CJO=0.130n  VJ=0.390)
Dbody   21   s2    DBODY
.MODEL DBODY  D(IS=8p  N=1.05  RS=0.5m  IKF=0.5  EG=1.08  TT=30n)
Rdiode  d1  21    4.25m  TC=2.5m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a     a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   0.327n
.MODEL     DGD    D(M=0.584  CJO=0.327n  VJ=1.20)
Rpar      b    d2   1Meg
Dgd       d2   a    DGD
Rpar2     d2   a    10Meg
Cgs       g2   s2   0.864n
.ENDS
*$
